20CN网络安全小组论坛 - 菜鸟乐园 - ASCII格式的ps命令（转）

论坛: 菜鸟乐园标题: ASCII格式的ps命令（转）

作者: bridex [bridex]

论坛用户

ADAM

隆重退出ps.vbs，可以在命令行方式执行vbs文件，可以查看服务器上的进程然后kiss掉你不喜欢的进程了！

''''********************************************************************
''''*
''''* File: PS.vbs
''''* Created: March 1999
''''* Version: 1.0
''''*
''''* Main Function: Gets CPU information for a machine.
''''*
''''* PS.vbs [/S <server>] [/U <username>] [/W <password>]
''''* [/O <outputfile>]
''''*
''''* Copyright (C) 1999 Microsoft Corporation
''''*
''''********************************************************************

OPTION EXPLICIT

''''Define constants
CONST CONST_ERROR = 0
CONST CONST_WSCRIPT = 1
CONST CONST_CSCRIPT = 2
CONST CONST_SHOW_USAGE = 3
CONST CONST_PROCEED = 4

''''Declare variables
Dim intOpMode, i
Dim strServer, strUserName, strPassword, strOutputFile
Dim intSortProperty, intWidth, intSortOrder
ReDim strProperties(2), intWidths(2)

''''Make sure the host is csript, if not then abort
VerifyHostIsCscript()

''''Parse the command line
intOpMode = intParseCmdLine(strServer , _
strUserName , _
strPassword , _
strOutputFile )

Select Case intOpMode

Case CONST_SHOW_USAGE
Call ShowUsage()

Case CONST_PROCEED
Call ListJobs(strServer , _
strOutputFile , _
strUserName , _
strPassword , _
intSortOrder , _
intSortProperty , _
intWidth , _
strProperties , _
intWidths )

Case CONST_ERROR
''''Do Nothing

Case Else ''''Default -- should never happen
Call Wscript.Echo("Error occurred in passing parameters.")

End Select

''''********************************************************************
''''* End of Script
''''********************************************************************

''''********************************************************************
''''*
''''* Sub ListJobs()
''''*
''''* Purpose: Gets CPU information for a machine.
''''*
''''* Input: strServer a machine name
''''* strOutputFile an output file name
''''* strUserName the current user''''s name
''''* strPassword the current user''''s password
''''*
''''* Output: Results are either printed on screen or saved in strOutputFile.
''''*
''''********************************************************************

Private Sub ListJobs(strServer , _
strOutputFile , _
strUserName , _
strPassword , _
intSortOrder , _
intSortProperty , _
intWidth , _
strProperties , _
intWidths )

ON ERROR RESUME NEXT

Dim objFileSystem, objOutputFile, objService, strQuery, strMessage
Dim objEnumerator, objInstance
Dim k, i, j, intUBound

''''Open a text file for output if the file is requested
If Not IsEmpty(strOutputFile) Then
If (NOT blnOpenFile(strOutputFile, objOutputFile)) Then
Call Wscript.Echo ("Could not open an output file.")
Exit Sub
End If
End If

''''Establish a connection with the server.
If blnConnect("root\cimv2" , _
strUserName , _
strPassword , _
strServer , _
objService ) Then
Call Wscript.Echo("")
Call Wscript.Echo("Please check the server name, " _
& "credentials and WBEM Core.")
Exit Sub
End If

''''Set the query string.
strQuery = "Select processid, name, executablepath From Win32_Process"

''''Now execute the query.

intUBound = UBound(strProperties)
''''Need to use redim so the last dimension can be resized
ReDim strResults(intUBound, 0), intOrder(0), strArray(0)

Set objEnumerator = objService.ExecQuery(strQuery,,0)
If Err.Number Then
Print "Error 0x" & CStr(Hex(Err.Number)) & " occurred during the query."
If Err.Description <> "" Then
Print "Error description: " & Err.Description & "."
End If
Err.Clear
Exit Sub
End If

''''Properties to get
strProperties(0) = "processid"
strProperties(1) = "name"
strProperties(2) = "executablepath"
intWidths(1) = 15
intWidths(0) = 15
intWidths(2) = 40

''''Read properties of processes into arrays.
i = 0
For Each objInstance in objEnumerator
If objInstance is nothing Then
Exit For
End If
ReDim Preserve strResults(intUBound, i), intOrder(i), strArray(i)
For j = 0 To intUBound
Select Case LCase(strProperties(j))
Case "processid"
strResults(j, i) = objInstance.properties_(strProperties(j))
If strResults(j, i) < 0 Then
''''4294967296 is 0x100000000.
strResults(j, i) = CStr(strResults(j, i) + 4294967296)
End If
Case "owner"
Dim strDomain, strUser
Call objInstance.GetOwner(strUser, strDomain)
strResults(j, i) = strDomain & "\" & strUser
Case Else
strResults(j, i) = CStr _
(objInstance.properties_(strProperties(j)))
End Select
If Err.Number Then
Err.Clear
strResults(j, i) = "(null)"
End If
Next
intOrder(i) = i
''''Copy the property values to be sorted.
strArray(i) = strResults(0, i)
i = i + 1
If Err.Number Then
Err.Clear
End If
Next

''''Check the data type of the property to be sorted
k = CDbl(strArray(0))
If Err.Number Then ''''not a number
Err.Clear
Else ''''a number
''''Pack empty spaces at the begining of each number
For j = 0 To UBound(strArray)
''''Assume the longest number would be less than 40 digits.
strArray(j) = strPackString(strArray(j), 40, 0, 0)
Next
End If

If i > 0 Then
''''Print the header
strMessage = vbCRLF & Space(2)
For j = 0 To intUBound
strMessage = strMessage & UCase(strPackString(strProperties(j), _
intWidths(j), 1, True))
Next
WriteLine strMessage & vbCRLF, objOutputFile

''''Sort strArray
Call SortArray(strArray, 1, intOrder, 0)

For j = 0 To intUBound
''''First copy results to strArray and change the order of elements
For k = 0 To i-1 ''''i is number of instances retrieved.
strArray(k) = strResults(j, intOrder(k))
Next
''''Now copy results back to strResults.
For k = 0 To i-1 ''''i is number of instances retrieved.
strResults(j, k) = strArray(k)
Next
Next

For k = 0 To i-1
strMessage = Space(2)
For j = 0 To intUBound
strMessage = strMessage & strPackString(strResults(j, k), _
intWidths(j), 1, True)
Next
WriteLine strMessage, objOutputFile
Next
End If

If IsObject(objOutputFile) Then
objOutputFile.Close
Call Wscript.Echo ("Results are saved in file " & strOutputFile & ".")
End If

End Sub

''''********************************************************************
''''*
''''* Function intParseCmdLine()
''''*
''''* Purpose: Parses the command line.
''''* Input:
''''*
''''* Output: strServer a remote server ("" = local server")
''''* strUserName the current user''''s name
''''* strPassword the current user''''s password
''''* strOutputFile an output file name
''''*
''''********************************************************************
Private Function intParseCmdLine( ByRef strServer, _
ByRef strUserName, _
ByRef strPassword, _
ByRef strOutputFile )

ON ERROR RESUME NEXT

Dim strFlag
Dim intState, intArgIter
Dim objFileSystem

If Wscript.Arguments.Count > 0 Then
strFlag = Wscript.arguments.Item(0)
End If

If IsEmpty(strFlag) Then ''''No arguments have been received
intParseCmdLine = CONST_PROCEED
Exit Function
End If

''''Check if the user is asking for help or is just confused
If (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "?") _
OR (strFlag="h") Then
intParseCmdLine = CONST_SHOW_USAGE
Exit Function
End If

''''Retrieve the command line and set appropriate variables
intArgIter = 0
Do While intArgIter <= Wscript.arguments.Count - 1
Select Case Left(LCase(Wscript.arguments.Item(intArgIter)),2)

Case "/s"
If Not blnGetArg("Server", strServer, intArgIter) Then
intParseCmdLine = CONST_ERROR
Exit Function
End If
intArgIter = intArgIter + 1

Case "/o"
If Not blnGetArg("Output File", strOutputFile, intArgIter) Then
intParseCmdLine = CONST_ERROR
Exit Function
End If
intArgIter = intArgIter + 1

Case "/u"
If Not blnGetArg("User Name", strUserName, intArgIter) Then
intParseCmdLine = CONST_ERROR
Exit Function
End If
intArgIter = intArgIter + 1

Case "/w"
If Not blnGetArg("User Password", strPassword, intArgIter) Then
intParseCmdLine = CONST_ERROR
Exit Function
End If
intArgIter = intArgIter + 1

Case Else ''''We shouldn''''t get here
Call Wscript.Echo("Invalid or misplaced parameter: " _
& Wscript.arguments.Item(intArgIter) & vbCRLF _
& "Please check the input and try again," & vbCRLF _
& "or invoke with ''''/?'''' for help with the syntax.")
Wscript.Quit

End Select

Loop ''''** intArgIter <= Wscript.arguments.Count - 1

If IsEmpty(intParseCmdLine) Then _
intParseCmdLine = CONST_PROCEED

End Function

''''********************************************************************
''''*
''''* Sub ShowUsage()
''''*
''''* Purpose: Shows the correct usage to the user.
''''*
''''* Input: None
''''*
''''* Output: Help messages are displayed on screen.
''''*
''''********************************************************************
Private Sub ShowUsage()

Wscript.Echo ""
Wscript.Echo "Lists all jobs currently running on a machine."
Wscript.Echo ""
Wscript.Echo "SYNTAX:"
Wscript.Echo " PS.vbs [/S <server>] [/U <username>]" _
&" [/W <password>]"
Wscript.Echo " [/O <outputfile>]"
Wscript.Echo ""
Wscript.Echo "PARAMETER SPECIFIERS:"
Wscript.Echo " server A machine name."
Wscript.Echo " username The current user''''s name."
Wscript.Echo " password Password of the current user."
Wscript.Echo " outputfile The output file name."
Wscript.Echo ""
Wscript.Echo "EXAMPLE:"
Wscript.Echo "1. cscript PS.vbs"
Wscript.Echo " List the jobs running on the current machine."
Wscript.Echo "2. cscript PS.vbs /S MyMachine2"
Wscript.Echo " List the jobs running on the machine MyMachine2."

End Sub

''''********************************************************************
''''* General Routines
''''********************************************************************

''''********************************************************************
''''*
''''* Sub SortArray()
''''* Purpose: Sorts an array and arrange another array accordingly.
''''* Input: strArray the array to be sorted
''''* blnOrder True for ascending and False for descending
''''* strArray2 an array that has exactly the same number of
''''* elements as strArray
''''* and will be reordered together with strArray
''''* blnCase indicates whether the order is case sensitive
''''* Output: The sorted arrays are returned in the original arrays.
''''* Note: Repeating elements are not deleted.
''''*
''''********************************************************************

Private Sub SortArray(strArray, blnOrder, strArray2, blnCase)

ON ERROR RESUME NEXT

Dim i, j, intUbound

If IsArray(strArray) Then
intUbound = UBound(strArray)
Else
Print "Argument is not an array!"
Exit Sub
End If

blnOrder = CBool(blnOrder)
blnCase = CBool(blnCase)
If Err.Number Then
Print "Argument is not a boolean!"
Exit Sub
End If

i = 0
Do Until i > intUbound-1
j = i + 1
Do Until j > intUbound
If blnCase Then ''''Case sensitive
If (strArray(i) > strArray(j)) and blnOrder Then
Swap strArray(i), strArray(j) ''''swaps element i and j
Swap strArray2(i), strArray2(j)
ElseIf (strArray(i) < strArray(j)) and Not blnOrder Then
Swap strArray(i), strArray(j) ''''swaps element i and j
Swap strArray2(i), strArray2(j)
ElseIf strArray(i) = strArray(j) Then
''''Move element j to next to i
If j > i + 1 Then
Swap strArray(i+1), strArray(j)
Swap strArray2(i+1), strArray2(j)
End If
End If
Else ''''Not case sensitive
If (LCase(strArray(i)) > LCase(strArray(j))) and blnOrder Then
Swap strArray(i), strArray(j) ''''swaps element i and j
Swap strArray2(i), strArray2(j)
ElseIf (LCase(strArray(i)) < LCase(strArray(j))) and _
Not blnOrder Then
Swap strArray(i), strArray(j) ''''swaps element i and j
Swap strArray2(i), strArray2(j)
ElseIf LCase(strArray(i)) = LCase(strArray(j)) Then
''''Move element j to next to i
If j > i + 1 Then
Swap strArray(i+1), strArray(j)
Swap strArray2(i+1), strArray2(j)
End If
End If
End If
j = j + 1
Loop
i = i + 1
Loop

End Sub

～
～
～
～
～

''''********************************************************************
''''*
''''* Sub Swap()
''''* Purpose: Exchanges values of two strings.
''''* Input: strA a string
''''* strB another string
''''* Output: Values of strA and strB are exchanged.
''''*
''''********************************************************************

Private Sub Swap(ByRef strA, ByRef strB)

Dim strTemp

strTemp = strA
strA = strB
strB = strTemp
strb = 4/0
End Sub

''''********************************************************************
''''*
''''* Function strPackString()
''''*
''''* Purpose: Attaches spaces to a string to increase the length to intWidth.
''''*
''''* Input: strString a string
''''* intWidth the intended length of the string
''''* blnAfter Should spaces be added after the string?
''''* blnTruncate specifies whether to truncate the string or not if
''''* the string length is longer than intWidth
''''*
''''* Output: strPackString is returned as the packed string.
''''*
''''********************************************************************
Private Function strPackString( ByVal strString, _
ByVal intWidth, _
ByVal blnAfter, _
ByVal blnTruncate)

ON ERROR RESUME NEXT

intWidth = CInt(intWidth)
blnAfter = CBool(blnAfter)
blnTruncate = CBool(blnTruncate)

If Err.Number Then
Call Wscript.Echo ("Argument type is incorrect!")
Err.Clear
Wscript.Quit
End If

If IsNull(strString) Then
strPackString = "null" & Space(intWidth-4)
Exit Function
End If

strString = CStr(strString)
If Err.Number Then
Call Wscript.Echo ("Argument type is incorrect!")
Err.Clear
Wscript.Quit
End If

If intWidth > Len(strString) Then
If blnAfter Then
strPackString = strString & Space(intWidth-Len(strString))
Else
strPackString = Space(intWidth-Len(strString)) & strString & " "
End If
Else
If blnTruncate Then
strPackString = Left(strString, intWidth-1) & " "
Else
strPackString = strString & " "
End If
End If

End Function

''''********************************************************************
''''*
''''* Function blnGetArg()
''''*
''''* Purpose: Helper to intParseCmdLine()
''''*
''''* Usage:
''''*
''''* Case "/s"
''''* blnGetArg ("server name", strServer, intArgIter)
''''*
''''********************************************************************
Private Function blnGetArg ( ByVal StrVarName, _
ByRef strVar, _
ByRef intArgIter)

blnGetArg = False ''''failure, changed to True upon successful completion

If Len(Wscript.Arguments(intArgIter)) > 2 then
If Mid(Wscript.Arguments(intArgIter),3,1) = ":" then
If Len(Wscript.Arguments(intArgIter)) > 3 then
strVar = Right(Wscript.Arguments(intArgIter), _
Len(Wscript.Arguments(intArgIter)) - 3)
blnGetArg = True
Exit Function
Else
intArgIter = intArgIter + 1
If intArgIter > (Wscript.Arguments.Count - 1) Then
Call Wscript.Echo( "Invalid " & StrVarName & ".")
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If

strVar = Wscript.Arguments.Item(intArgIter)
If Err.Number Then
Call Wscript.Echo( "Invalid " & StrVarName & ".")
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If

If InStr(strVar, "/") Then
Call Wscript.Echo( "Invalid " & StrVarName)
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If

blnGetArg = True ''''success
End If
Else
strVar = Right(Wscript.Arguments(intArgIter), _
Len(Wscript.Arguments(intArgIter)) - 2)
blnGetArg = True ''''success
Exit Function
End If
Else
intArgIter = intArgIter + 1
If intArgIter > (Wscript.Arguments.Count - 1) Then
Call Wscript.Echo( "Invalid " & StrVarName & ".")
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If

strVar = Wscript.Arguments.Item(intArgIter)
If Err.Number Then
Call Wscript.Echo( "Invalid " & StrVarName & ".")
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If

If InStr(strVar, "/") Then
Call Wscript.Echo( "Invalid " & StrVarName)
Call Wscript.Echo( "Please check the input and try again.")
Exit Function
End If
blnGetArg = True ''''success
End If
End Function

''''********************************************************************
''''*
''''* Function blnConnect()
''''*
''''* Purpose: Connects to machine strServer.
''''*
''''* Input: strServer a machine name
''''* strNameSpace a namespace
''''* strUserName name of the current user
''''* strPassword password of the current user
''''*
''''* Output: objService is returned as a service object.
''''* strServer is set to local host if left unspecified
''''*
''''********************************************************************
Private Function blnConnect(ByVal strNameSpace, _
ByVal strUserName, _
ByVal strPassword, _
ByRef strServer, _
ByRef objService)

ON ERROR RESUME NEXT

Dim objLocator, objWshNet

blnConnect = False ''''There is no error.

''''Create Locator object to connect to remote CIM object manager
Set objLocator = CreateObject("WbemScripting.SWbemLocator")
If Err.Number then
Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
" occurred in creating a locator object." )
If Err.Description <> "" Then
Call Wscript.Echo( "Error description: " & Err.Description & "." )
End If
Err.Clear
blnConnect = True ''''An error occurred
Exit Function
End If

''''Connect to the namespace which is either local or remote
Set objService = objLocator.ConnectServer (strServer, strNameSpace, _
strUserName, strPassword)
ObjService.Security_.impersonationlevel = 3
If Err.Number then
Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & _
" occurred in connecting to server " _
& strServer & ".")
If Err.Description <> "" Then
Call Wscript.Echo( "Error description: " & Err.Description & "." )
End If
Err.Clear
blnConnect = True ''''An error occurred
End If

''''Get the current server''''s name if left unspecified
If IsEmpty(strServer) Then
Set objWshNet = CreateObject("Wscript.Network")
strServer = objWshNet.ComputerName
End If

End Function

''''********************************************************************
''''*
''''* Sub VerifyHostIsCscript()
''''*
''''* Purpose: Determines which program is used to run this script.
''''*
''''* Input: None
''''*
''''* Output: If host is not cscript, then an error message is printed
''''* and the script is aborted.
''''*
''''********************************************************************
Sub VerifyHostIsCscript()

ON ERROR RESUME NEXT

Dim strFullName, strCommand, i, j, intStatus

strFullName = WScript.FullName

If Err.Number then
Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & " occurred." )
If Err.Description <> "" Then
Call Wscript.Echo( "Error description: " & Err.Description & "." )
End If
intStatus = CONST_ERROR
End If

i = InStr(1, strFullName, ".exe", 1)
If i = 0 Then
intStatus = CONST_ERROR
Else
j = InStrRev(strFullName, "\", i, 1)
If j = 0 Then
intStatus = CONST_ERROR
Else
strCommand = Mid(strFullName, j+1, i-j-1)
Select Case LCase(strCommand)
Case "cscript"
intStatus = CONST_CSCRIPT
Case "wscript"
intStatus = CONST_WSCRIPT
Case Else ''''should never happen
Call Wscript.Echo( "An unexpected program was used to " _
& "run this script." )
Call Wscript.Echo( "Only CScript.Exe or WScript.Exe can " _
& "be used to run this script." )
intStatus = CONST_ERROR
End Select
End If
End If

If intStatus <> CONST_CSCRIPT Then
Call WScript.Echo( "Please run this script using CScript." & vbCRLF & _
"This can be achieved by" & vbCRLF & _
"1. Using ""CScript PS.VBS arguments"" for Windows 95/98 or" _
& vbCRLF & "2. Changing the default Windows Scripting Host " _
& "setting to CScript" & vbCRLF & " using ""CScript " _
& "//H:CScript //S"" and running the script using" & vbCRLF & _
" ""PS.VBS arguments"" for Windows NT/2000." )
WScript.Quit
End If

End Sub

''''********************************************************************
''''*
''''* Sub WriteLine()
''''* Purpose: Writes a text line either to a file or on screen.
''''* Input: strMessage the string to print
''''* objFile an output file object
''''* Output: strMessage is either displayed on screen or written to a file.
''''*
''''********************************************************************
Sub WriteLine(ByVal strMessage, ByVal objFile)

On Error Resume Next
If IsObject(objFile) then ''''objFile should be a file object
objFile.WriteLine strMessage
Else
Call Wscript.Echo( strMessage )
End If

End Sub

''''********************************************************************
''''*
''''* Function blnErrorOccurred()
''''*
''''* Purpose: Reports error with a string saying what the error occurred in.
''''*
''''* Input: strIn string saying what the error occurred in.
''''*
''''* Output: displayed on screen
''''*
''''********************************************************************
Private Function blnErrorOccurred (ByVal strIn)

If Err.Number Then
Call Wscript.Echo( "Error 0x" & CStr(Hex(Err.Number)) & ": " & strIn)
If Err.Description <> "" Then
Call Wscript.Echo( "Error description: " & Err.Description)
End If
Err.Clear
blnErrorOccurred = True
Else
blnErrorOccurred = False
End If

End Function

''''********************************************************************
''''*
''''* Function blnOpenFile
''''*
''''* Purpose: Opens a file.
''''*
''''* Input: strFileName A string with the name of the file.
''''*
''''* Output: Sets objOpenFile to a FileSystemObject and setis it to
''''* Nothing upon Failure.
''''*
''''********************************************************************
Private Function blnOpenFile(ByVal strFileName, ByRef objOpenFile)

ON ERROR RESUME NEXT

Dim objFileSystem

Set objFileSystem = Nothing

If IsEmpty(strFileName) OR strFileName = "" Then
blnOpenFile = False
Set objOpenFile = Nothing
Exit Function
End If

''''Create a file object
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
If blnErrorOccurred("Could not create filesystem object.") Then
blnOpenFile = False
Set objOpenFile = Nothing
Exit Function
End If

''''Open the file for output
Set objOpenFile = objFileSystem.OpenTextFile(strFileName, 8, True)
If blnErrorOccurred("Could not open") Then
blnOpenFile = False
Set objOpenFile = Nothing
Exit Function
End If
blnOpenFile = True

End Function

''''********************************************************************
''''* *
''''* End of File *
''''* *
''''********************************************************************

真的够Cool！！！

地主发表时间: 04-03-26 21:31